$Title Equilibrium Unemployment Model Static MCP VERSION

$ontext
This program appears in Appendix A of:

E.J. Balistreri (2002) "Operationalizing equilibrium 
unemployment: a general equilibrium external economies 
approach," Journal of Economics Dynamics and Control
23/3: 347-374.

Edward J. Balistreri
Research Division
U.S. International Trade Commission
ebalistreri@usitc.gov
$offtext

Parameters
LS0	Benchmark Value of Labor Supply,
L0	Value of Labor Endowment,
C0	Benchmark Value of Consumption,
U0	Benchmark Unemployment Rate,
TAX	TAX on Leisure (zero in benchmark),
Y_TAX	TAX on Output (zero in benchmark),
SIG	Exponent on LS in externality,
ETA	Exponent on U in externality,
alpha	Value share in C-D utility function,
phi	Constant scale factor in utility function;

LS0 = 150;L0 = 250;C0 = 250;U0 = 0.1; TAX = 0.0;Y_TAX = 0.0;

SIG	= 0.5;	ETA	= 0.1;

alpha	=LS0/C0;
phi	=((1-u0)**alpha);

Positive Variables
	W	Utility
	E	Employed Labor Index
	PC	Price of Consumption
	PL	Reservation wage
	WAGE	Wage paid to Employed
	U	Unemployment Rate
	RA	Income;
Equations
	PROF_C		Zero Profit for Utility,
	PROF_E		Zero Profit for E,
	MKT_PC		Market Clearence for PC,
	MKT_PL		Market Clearence for PL,
	MKT_WAGE	Market Clearence for WAGE,
	UU		Unemploy Def;

PROF_C..
	((wage	*(1+Y_tax))	**(alpha) *
	 (PL	* (1+tax))	**(1-alpha)) =g= PC;

PROF_E..
	pl =g=	wage*(1-u0)*((E/((1-u0)))**(SIG))*(u/u0)**(ETA);


MKT_PL..
	L0 - 
	phi*(1-alpha)*W*C0*
	(wage*(1+Y_tax))**(alpha) *
	(PL*(1+tax))**(1-alpha)/
	(PL*(1+tax)) 
	- E*(LS0)/(1-u) =g=0;

MKT_WAGE..
	E*(LS0) - phi*(alpha)*W*C0*
	(wage*(1+Y_tax))**(alpha) * 
	(PL*(1+tax))**(1-alpha)/
	(wage*(1+Y_tax)) =g=0;

MKT_PC..
	W*C0*PC*phi =g=  PL*L0
	+TAX*PL*
	phi*(1-alpha)*W*C0*
	(wage*(1+Y_tax))**(alpha) *
	(PL*(1+tax))**(1-alpha)/
	(PL*(1+tax)) 
	+Y_TAX*wage*
	phi*(alpha)*W*C0*
	(wage*(1+Y_tax))**(alpha) *
	(PL*(1+tax))**(1-alpha)/
	(wage*(1+Y_tax));

UU..
	u=e=1-E*(LS0)/
	(L0-
	(phi*(1-alpha)*W*C0*
	(wage*(1+Y_tax))**(alpha) * 
	(PL*(1+tax))**(1-alpha)/(PL*(1+tax))));

Model EQUS /PROF_C.W,PROF_E.E,
	    MKT_PC.PC,MKT_PL.PL,MKT_WAGE.WAGE,
	    UU.U/;

*	Set the Benchmark Values and check Replication
$eolcom !

E.L = (1-u0);		! Employed Index = (1-u0) (Employed = E*LS0)
W.L = 1;		! Normalize Utility index to One
U.L = u0;		! Unemployment rate at the Benchmark
PC.l=1/phi;		! The price of consumption reflects Benchmark U
PL.fx=1;		! Select PL as the Numerare (b/c income bal. is in MKT_PC)
WAGE.l=PL.l/(1-u0);	! The wage inclusive of the Wage Premium at U

EQUS.ITERLIM =0;
SOLVE EQUS USING MCP;