$Title Equilibrium Unemployment Model Static MPSGE VERSION

$ontext
This program defines the MPSGE version of the program 
that appears in Appendix A of:

E.J. Balistreri (2002) "Operationalizing equilibrium 
unemployment: a general equilibrium external economies 
approach," Journal of Economics Dynamics and Control
23/3: 347-374.

Edward J. Balistreri
Research Division
U.S. International Trade Commission
ebalistreri@usitc.gov
$offtext

Parameters
LS0	Benchmark Value of Labor Supply,
L0	Value of Labor Endowment,
C0	Benchmark Value of Consumption,
U0	Benchmark Unemployment Rate,
TAX	TAX on Leisure (zero in benchmark),
Y_TAX	TAX on Output (zero in benchmark),
SIG	Exponent on LS in externality,
ETA	Exponent on U in externality,
alpha	Value share in C-D utility function,
phi	Constant scale factor in utility function;

LS0 = 150;L0 = 250;C0 = 250;U0 = 0.1; TAX = 0.0;Y_TAX = 0.0;

SIG	= 0.5;	ETA	= 0.1;

alpha	=LS0/C0;
phi	=((1-u0)**alpha);

$ONTEXT

$MODEL:STAT1

$Sectors:
        W	! Welfare Index
	WF	! Work Force

$Commodities:
        PC   ! Price index on Consumption
        PL   ! Reservation Wage
	WAGE ! Wage Index

$Consumers:
        RA      ! Representative agent

$Auxiliary:
	U	! Unemployment Rate Definition
	W_ADJ	! Wage Adjustment
	L_ADJ	! Labor Adjustment

$PROD:W s:1
        O:PC	Q:(C0)
        I:WAGE	Q:(LS0*(1-u0)) P:(1/(1-u0)) 	A:RA T:Y_TAX
	I:PL	Q:(L0-LS0)			A:RA T:TAX

$PROD:WF
	O:WAGE	Q:(LS0) A:RA N:W_ADJ M:-1
	I:PL	Q:(LS0) 

$Demand:RA
        D:PC	Q:C0	
        E:PL	Q:L0
	E:WAGE	Q:(LS0) R:L_ADJ

$Constraint:U
	U=e=1-(WF+L_ADJ)/(WF);

$Constraint:W_ADJ
	W_ADJ*WF=e=L_ADJ;

$Constraint:L_ADJ
	L_ADJ=e= WF*(1-u0)*((((WF+L_ADJ)/(1-u0))**(SIG))*(u/u0)**(ETA))
		-WF;

$offtext
$sysinclude mpsgeset STAT1

*	Set the Benchmark Values and check Replication
$eolcom !

WF.L =1;		! Employed Index = (1-u0) (Employed = E*LS0)
W.L = 1;		! Normalize Utility index to One
U.L = u0;		! Unemployment rate at the Benchmark
PC.l=1;			! The price of consumption reflects Benchmark U
PL.fx=1;		! Select PL as the Numerare (b/c income bal. is in MKT_PC)
WAGE.l=PL.l/(1-u0);	! The wage inclusive of the Wage Premium at U

W_ADJ.lo=-inf;
L_ADJ.Lo=-inf;
W_ADJ.L=-u0;
L_ADJ.L=-u0;

stat1.ITERLIM = 0;
$include stat1.gen
solve stat1 using mcp;